#include <amxmodx>
#include <fun>
#include <fakemeta>
#include <hamsandwich>
#include <engine>

#define ZOMBIE //Закоментировать если будите использовать не на зомби моде

#if defined ZOMBIE
#include <zombieplague>
#endif

new g_connect
#define get_weapon(%0)   (entity_get_int(%0, EV_INT_impulse) == 20144)
#define set_weapon(%0)   entity_set_int(%0, EV_INT_impulse, 20144)

#define get_bit(%1,%2)   ((%1 & (1 << (%2 & 31))) ? true : false)
#define set_bit(%1,%2)	 %1 |= (1 << (%2 & 31))
#define reset_bit(%1,%2) %1 &= ~(1 << (%2 & 31))

const PRIMARY_WEAPONS_BIT_SUM = 
(1<<CSW_SCOUT)|(1<<CSW_XM1014)|(1<<CSW_MAC10)|(1<<CSW_AUG)|(1<<CSW_UMP45)|(1<<CSW_SG550)|(1<<CSW_GALIL)|(1<<CSW_FAMAS)|(1<<CSW_AWP)|(1<<
CSW_MP5NAVY)|(1<<CSW_M249)|(1<<CSW_M3)|(1<<CSW_M4A1)|(1<<CSW_TMP)|(1<<CSW_G3SG1)|(1<<CSW_SG552)|(1<<CSW_AK47)|(1<<CSW_P90)

enum 
{
    IDLE = 0,
    RELOAD,
    DRAW,
    SHOOT
}

new const trace_attack[][] = 
{
    "func_breakable", 
    "func_wall", 
    "func_door",
    "func_plat", 
    "func_rotating", 
    "worldspawn" 
}

new const damage_entity[][] =
{
    "player",
    "func_breakable",
    "hostage_entity"
}

new const sound_shoot[] = "weapons/m14ebr.wav"

new const other_sounds[][] =
{
    "weapons/m14_clipin.wav",
    "weapons/m14_clipout.wav",
    "weapons/m14_draw.wav"
}

new const sprites_weapon[][] =
{
    "sprites/weapon_m14ebr.txt",
    "sprites/640hud47.spr",
    "sprites/640hud7.spr"
}

new const models_weapon[][] =
{
    "models/zm/v_m14ebr.mdl",
    "models/zm/p_m14ebr.mdl",
    "models/zm/w_m14ebr.mdl"
}

const AMMO_CLIP = 20
const AMMO_MAX = 120
const Float:DAMAGE = 2.0
const Float:SPEED = 0.15
const Float:RECOIL = 2.0

new g_weapon_m14ebr[33]
new g_origin_event_weapon, g_shell_index

#if defined ZOMBIE
new const item_name[] = "M14 Ebr"
const item_cost = 5              
new g_item
#endif

public plugin_init()
{
       register_plugin("[Z] Weapon: M14 Ebr", "1.0", "batcon")

       RegisterHam(Ham_Item_Deploy, "weapon_galil", "Ham_Item_Deploy_Post", 1)
       RegisterHam(Ham_Weapon_Reload, "weapon_galil", "Ham_Weapon_Reload_Pre")
       RegisterHam(Ham_Item_PostFrame, "weapon_galil", "Ham_Item_PostFrame_Pre")
       RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_galil", "Ham_Weapon_PrimaryAttack_Pre")
       RegisterHam(Ham_Item_AddToPlayer, "weapon_galil", "Ham_Item_AddToPlayer_Post", 1)
       RegisterHam(Ham_Weapon_WeaponIdle, "weapon_galil", "Ham_Weapon_WeaponIdle_Pre")
       
       static i

       for(i = 0 ;i < sizeof trace_attack; i++)
       {
                   RegisterHam(Ham_TraceAttack, trace_attack[i], "Ham_TraceAttack_Post", 1)
       }

       for(i = 0 ;i < sizeof damage_entity; i++)
       {
                   RegisterHam(Ham_TraceAttack, damage_entity[i], "Ham_TraceAttack_Pre")	
       }

       register_forward(FM_PlaybackEvent, "FM_PlaybackEvent_Pre")
       register_forward(FM_UpdateClientData, "FM_UpdateClientData_Post", 1)
       register_forward(FM_SetModel, "FM_SetModel_Pre")

       #if defined ZOMBIE
       g_item = zp_register_extra_item(item_name, item_cost, ZP_TEAM_HUMAN)
       #endif

       register_clcmd("weapon_m14ebr", "weapon_hook")
}

public plugin_precache()
{
       static i

       for(i = 0; i < sizeof models_weapon; i++)
       {
		precache_model(models_weapon[i])
       }

       for(i = 0; i < sizeof sprites_weapon; i++)
       {
		precache_generic(sprites_weapon[i])
       }

       for(i = 0; i < sizeof other_sounds; i++)
       {
		precache_sound(other_sounds[i])
       }

       precache_sound(sound_shoot)
       g_shell_index = precache_model("models/rshell.mdl")

       register_forward(FM_PrecacheEvent, "FM_PrecacheEvent_Post", 1)
}

public plugin_natives()
{
       register_native("z_weapon_m14_ebr", "give_m14", 1)
}

#if defined ZOMBIE
public zp_extra_item_selected(id, item)
{
       if(item == g_item)
       {
              give_m14(id)
       }
}

public zp_user_infected_post(id)
{
       g_weapon_m14ebr[id] = false
}
#endif

public weapon_hook(id) 
{
       engclient_cmd(id, "weapon_galil")
       return PLUGIN_HANDLED
}

public client_putinserver(id)
{
       set_bit(g_connect, id)
}

public client_disconnect(id)
{
       g_weapon_m14ebr[id] = false
}

public FM_PrecacheEvent_Post(type, name[])
{
       if(equal("events/galil.sc", name))
       {
                g_origin_event_weapon = get_orig_retval()
                return FMRES_HANDLED
       }

       return FMRES_IGNORED
}

public FM_PlaybackEvent_Pre(flags, invoker, eventid, Float:delay, Float:origin[3], Float:angles[3], Float:fparam1, Float:fparam2, iParam1, iParam2, bParam1, bParam2)
{
       if(eventid != g_origin_event_weapon)
       return FMRES_IGNORED

       if(!(1 < invoker <= get_maxplayers()))
       return FMRES_IGNORED

       playback_event(flags | FEV_HOSTONLY, invoker, eventid, delay, origin, angles, fparam1, fparam2, iParam1, iParam2, bParam1, bParam2)
       return FMRES_SUPERCEDE
}

public FM_UpdateClientData_Post(id, SendWeapons, CD_Handle)
{
       if(!is_user_alive(id))
       return FMRES_IGNORED

       static item; item = get_player_item(id)
	
       if(!get_weapon(item))
       return FMRES_IGNORED

       set_cd(CD_Handle, CD_flNextAttack, get_gametime() + 0.001)
       return FMRES_HANDLED
}

public give_m14(id)
{
       drop_weapons(id, 1)

       g_weapon_m14ebr[id] = true
       static weapon; weapon = give_item(id, "weapon_galil")
       set_weapon(weapon)
       set_ammo_clip(weapon, AMMO_CLIP)
       set_ammo(id, AMMO_MAX)
       entity_set_string(id, EV_SZ_viewmodel, models_weapon[0])
       entity_set_string(id, EV_SZ_weaponmodel, models_weapon[1]) 
       UTIL_PlayWeaponAnimation(id, DRAW)
       set_next_attack(id, 1.5)

       Weaponlist(id, "weapon_m14ebr", AMMO_MAX)
}

public Ham_Item_Deploy_Post(weapon_ent)
{
       if(!is_valid_ent(weapon_ent))
       return HAM_IGNORED

       static id; id = get_player(weapon_ent)

       if(!g_weapon_m14ebr[id])
       return HAM_IGNORED
       
       entity_set_string(id, EV_SZ_viewmodel, models_weapon[0]) 
       entity_set_string(id, EV_SZ_weaponmodel, models_weapon[1]) 
       UTIL_PlayWeaponAnimation(id, DRAW)
       set_next_attack(id, 1.5) 

       return HAM_IGNORED
}

public Ham_Weapon_Reload_Pre(weapon_ent)
{
       if(!is_valid_ent(weapon_ent))
       return HAM_IGNORED

       static id, clip
       id = get_player(weapon_ent)

       if(!g_weapon_m14ebr[id])
       return HAM_IGNORED

       if(get_ammo(id) <= 0 || get_ammo_clip(weapon_ent) >= AMMO_CLIP)
       return HAM_SUPERCEDE

       clip = get_ammo_clip(weapon_ent)

       set_ammo_clip(weapon_ent, 0)
       ExecuteHam(Ham_Weapon_Reload, weapon_ent)
       set_ammo_clip(weapon_ent, clip)

       UTIL_PlayWeaponAnimation(id, RELOAD) 
       set_next_attack(id, 3.0)
       set_next_idle(weapon_ent, 3.0)

       return HAM_SUPERCEDE
}

public Ham_Item_PostFrame_Pre(weapon_ent)
{
       if(!is_valid_ent(weapon_ent))
       return HAM_IGNORED

       static id; id = get_player(weapon_ent) 
       static ammo; ammo = get_ammo(id)
       static clip; clip = get_ammo_clip(weapon_ent)     
       static Float:NextAttack, Reload 

       if(!g_weapon_m14ebr[id])
       return HAM_IGNORED

       NextAttack = get_pdata_float(id, 83, 5) 
       Reload = get_pdata_int(weapon_ent, 54, 4)

       if(Reload && NextAttack <= 0.0)
       {
             static old; old = min(AMMO_CLIP - clip, ammo)  

             set_ammo_clip(weapon_ent, clip + old) 
             set_ammo(id, ammo - old)

             set_pdata_int(weapon_ent, 54, 0, 4)
             Reload = 0
       }

       return HAM_IGNORED
}

public Ham_Weapon_PrimaryAttack_Pre(weapon_ent)
{
       if(!is_valid_ent(weapon_ent))
       return HAM_IGNORED

       static id; id = get_player(weapon_ent)

       if(!g_weapon_m14ebr[id])
       return HAM_IGNORED

       if(get_ammo_clip(weapon_ent) == 0)
       return HAM_IGNORED

       ExecuteHam(Ham_Weapon_PrimaryAttack, weapon_ent)

       emit_sound(id, CHAN_WEAPON, sound_shoot, VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
       set_weapon_reloil(weapon_ent, RECOIL)
       UTIL_PlayWeaponAnimation(id, SHOOT)
       set_next_attack(id, SPEED) 
       set_next_idle(weapon_ent, 1.0)
       create_shell(weapon_ent, id, g_shell_index)

       return HAM_SUPERCEDE
}

public Ham_Weapon_WeaponIdle_Pre(weapon_ent)
{
       if(!is_valid_ent(weapon_ent))
       return HAM_IGNORED

       static id, Float:time_idle
       id = get_player(weapon_ent)

       if(!g_weapon_m14ebr[id])
       return HAM_IGNORED

       time_idle = get_pdata_float(weapon_ent, 48, 4)    

       if(time_idle > 0.0)
       return HAM_IGNORED

       UTIL_PlayWeaponAnimation(id, IDLE)

       set_next_idle(weapon_ent, 1.5)

       return HAM_SUPERCEDE
}

public Ham_Item_AddToPlayer_Post(weapon_ent, id)
{
       if(!is_valid_ent(weapon_ent))
       return HAM_IGNORED

       if(get_weapon(weapon_ent))
       {
              g_weapon_m14ebr[id] = true

	      Weaponlist(id, "weapon_m14ebr", AMMO_MAX)
              return HAM_HANDLED
       }
       
       Weaponlist(id, "weapon_galil", 90)

       return HAM_IGNORED
}

public Ham_TraceAttack_Post(entity, attacker, Float:damage, Float:fDir[3], ptr, damagetype)
{
       static item; item = get_player_item(attacker)

       if(!get_weapon(item))
       return HAM_HANDLED
	
       new Float:vecEnd[3]
   
       get_tr2(ptr, TR_vecEndPos, vecEnd);

       message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
       write_byte(TE_GUNSHOTDECAL)
       engfunc(EngFunc_WriteCoord, vecEnd[0])
       engfunc(EngFunc_WriteCoord, vecEnd[1])
       engfunc(EngFunc_WriteCoord, vecEnd[2])
       write_short(entity)
       write_byte(random_num(41, 45))
       message_end()

       return HAM_IGNORED
}

public Ham_TraceAttack_Pre(entity, attacker, Float:damage)
{
       if(get_bit(g_connect, attacker))
       {
                if(get_user_weapon(attacker) == CSW_GALIL && g_weapon_m14ebr[attacker])
                {
                         SetHamParamFloat(3, damage * DAMAGE)
                         return HAM_IGNORED
                } 
       }
       return HAM_IGNORED
}

public FM_SetModel_Pre(entity, model[])
{
       if(!is_valid_ent(entity))
       return FMRES_IGNORED
	
       static szClassName[33]
       entity_get_string(entity, EV_SZ_classname, szClassName, charsmax(szClassName))
		
       if(!equal(szClassName, "weaponbox"))
       return FMRES_IGNORED
	
       static id; id = entity_get_edict(entity, EV_ENT_owner)
	
       if(equal(model, "models/w_galil.mdl"))
       {
		static iStoredAugID; iStoredAugID = find_ent_by_owner(-1, "weapon_galil", entity)
	
		if(!is_valid_ent(iStoredAugID))
		return FMRES_IGNORED
	
		if(g_weapon_m14ebr[id])
		{			
			entity_set_model(entity, models_weapon[2])
                        g_weapon_m14ebr[id] = false

			return FMRES_SUPERCEDE
		}
       }

       return FMRES_IGNORED
}

public Weaponlist(player, weaponlist_name[], ammo)
{
       message_begin(MSG_ONE, get_user_msgid("WeaponList"), _, player)
       write_string(weaponlist_name) 
       write_byte(4)
       write_byte(ammo)
       write_byte(-1)
       write_byte(-1)
       write_byte(0)
       write_byte(17)
       write_byte(CSW_GALIL)
       write_byte(0)
       message_end()
}

stock set_ammo_clip(weapon, amount)
{
      set_pdata_int(weapon, 51, amount, 4)
}

stock set_ammo(player, amount)
{
      set_pdata_int(player, 380, amount, 5)
}

stock get_ammo(player)
{
      return get_pdata_int(player, 380, 5)
}

stock get_ammo_clip(weapon)
{
      return get_pdata_int(weapon, 51, 4)
}

stock get_player(weapon)
{
      return get_pdata_cbase(weapon, 41, 4)
}

stock get_player_item(player)
{
      return get_pdata_cbase(player, 373, 5)
}

stock set_next_attack(player, Float:time)
{
      set_pdata_float(player, 83, time, 5)
}

stock set_next_idle(weapon, Float:time)
{
      set_pdata_float(weapon, 48, time, 4)
}

stock set_weapon_reloil(weapon, Float:recoil)
{
      set_pdata_float(weapon, 62, recoil, 4)
}

stock create_shell(weapon, player, shell_index)
{
      set_pdata_int(weapon, 57, shell_index, 4)
      set_pdata_float(player, 111, get_gametime())
}

stock UTIL_PlayWeaponAnimation(const Player, const Sequence)
{
      entity_set_int(Player, EV_INT_weaponanim, Sequence)
	
      message_begin(MSG_ONE_UNRELIABLE, SVC_WEAPONANIM, .player = Player)
      write_byte(Sequence)
      write_byte(0)
      message_end()
}

stock drop_weapons(player, dropwhat)
{
     static weapons[32], num, i, weaponid
     num = 0
     get_user_weapons(player, weapons, num)
     
     for (i = 0; i < num; i++)
     {
          weaponid = weapons[i]
          
          if (dropwhat == 1 && ((1<<weaponid) & PRIMARY_WEAPONS_BIT_SUM))
          {
               static wname[32]
               get_weaponname(weaponid, wname, sizeof wname - 1)
               engclient_cmd(player, "drop", wname)
          }
     }
}